Arrondir

Voici quelques formules bien utiles pour arrondir des nombres.

Arrondir en un nombre entier

Arrondir à l'entier inférieur

  • En valeur relative

1,1 sera arrondi à 1 et -1,1 sera arrondi à -2.

=ENT(Nombre)

  • En valeur absolue

1,1 sera arrondi à 1, mais -1,1 sera arrondi à -1 : on arrondit à l'entier supérieur pour les nombres négatifs.

=ARRONDI.INF(Nombre;0)

Cette fonction revient à enlever les décimales d'un nombre.

Arrondir à l'entier supérieur

  • En valeur absolue

=ARRONDI.SUP(Nombre;0)

  • En valeur relative

=-ENT(-Nombre)

Arrondir à l'entier le plus proche

  • En valeur absolue

=ARRONDI(Nombre;0)

Pour les nombres positifs, si la première décimale de Nombre est 0, 1, 2, 3 ou 4 l'arrondi est à l'entier inférieur, sinon il est à l'entier supérieur. Pour les nombres négatifs, c'est l'inverse.

  • En valeur relative

=ENT(A19+0,5)

Pour les nombres positifs et négatifs, si la première décimale de Nombre est 0, 1, 2, 3 ou 4 l'arrondi est à l'entier inférieur.

Arrondir avec un certain nombre de décimales D

Dans toutes les formules qui suivent, vous pouvez spécifier un nombre de décimales négatif pour arrondir à la dizaine (D = -1), à la centaine (D = -2)...

Arrondi inférieur avec D décimales

  • En valeur absolue

=ARRONDI.INF(Nombre;D)

  • En valeur relative

=ENT(Nombre*10^D)/10^D

Arrondi supérieur avec D décimales

  • En valeur absolue

=ARRONDI.SUP(Nombre;D)

  • En valeur relative

=-ENT(-Nombre*10^D)/10^D

Arrondi au plus proche avec D décimales

  • En valeur absolue

=ARRONDI(Nombre;D)

  • En valeur relative

=ENT(Nombre*10^D+0,5)/10^D

Arrondir des nombres à x près

Par exemple pour arrondir des prix à 5 centimes près : x = 0,05.

Arrondi inférieur à x près

  • Pour des nombres positifs

=PLANCHER(Nombre;x)

  • Pour des nombres positifs ou négatifs, en valeur absolue

=SIGNE(Nombre)*ENT(ABS(Nombre)/x)*x

  • Pour des nombres positifs ou négatifs, en valeur relative

=ENT(Nombre/x)*x

Arrondi supérieur à x près

  • Pour des nombres positifs

=PLAFOND(Nombre;x)

  • Pour des nombres positifs ou négatifs, en valeur absolue

=-SIGNE(Nombre)*ENT(-ABS(Nombre)/x)*x

  • Pour des nombres positifs ou négatifs, en valeur relative

=-ENT(-Nombre/x)*x

Arrondi au plus proche à x près

  • Pour des nombres positifs

=ARRONDI.AU.MULTIPLE(Nombre;x)

Ne gère pas les nombres négatifs.
Nécessite l'Utilitaire d'analyse. Pour activer l'utilitaire d'analyse, cliquez sur Outils\Macros complémentaires et cochez Utilitaire d'analyse.

  • Pour des nombres positifs ou négatifs, en valeur absolue

=SIGNE(Nombre)*ENT(ABS(Nombre)/x+0,5)*x

  • Pour des nombres positifs ou négatifs, en valeur relative

=ENT(Nombre/x+0,5)*x

Arrondir à x près en commençant à partir de z

Exemple : vous voulez arrondir (supérieur, inférieur ou autre) à x = 5 centimes près mais en commençant par z = 1 centime. C'est-à-dire que vous voulez avoir des nombres comme 0,01 ; 0,06 ; 1,01, -0,04 ; -0,99... Dans toutes les formules précédentes remplacez "Nombre" par "Nombre-z" et rajoutez "+z" à la fin de la formule.

Mot clef associé à cette page :