Je voudrais dans une colonne faire la somme d'une cellule sur deux.

Pour additionner les lignes de la plage A1:A5 dont le numéro de ligne est pair :
=SOMMEPROD((MOD(LIGNE(A1:A5);2)=0)*(A1:A5))
explications : La fonction Ligne() : renvoie le numéro de la ligne
La fonction =Mod(ligne();2) : Lorsque le résultat de cette fonction est égal à 1, le numéro de la ligne est impair, si le résultat est égal à 0, le numéro de la ligne est pair.
Une autre façon d'écrire cette section de la formule :
=MOD(LIGNE(A1:A5);2)=0
Sélectionne les cellules B1:B5 dans la cellule active b1 , écris la formule suivante :
=MOD(LIGNE(A1:A5);2)=0
Valide la saisie de la formule en B1 par ctrl+ Maj + Enter, la formule est transformée en formule matricielle. Le résultat affiché en cellules B1:B5 est : Faux,Vrai,Faux,Vrai,Faux Dans une feuille de calcul excel, la valeur d'une cellule affichant "Vrai" = 1 , "Faux" = 0
L'autre façon d'écrire cette formule est :
=MOD(LIGNE(A1:A5);2)=0
Ecris cette formule dans une cellule
Sélectionne dans la barre des formules le texte LIGNE(A1:A5) de la formule, Appuie sur la touche F9, tu obtiens ce résultat:
LIGNE(A1:A5) est remplacé par une matrice des numéros de lignes de la plage de cellules. {1;2;3;4;5} La nouvelle formule est :
=MOD({1;2;3;4;5};2)=0
Chaque élément de la matrice est testé par la fonction Mod()
Tu peux inscrire chacune de ces formules dans une cellule pour tester chaque élément de la matrice par la fonction mod() et la valeur logique Faux ou Vrai s'affichera dans la cellule
Formule V.Logique V.Numérique =Mod(1;2)=0 = Faux ou 0 =Mod(2;2)=0 = Vrai ou 1 =Mod(3;2)=0 = Faux ou 0 =Mod(4;2)=0 = Vrai ou 1 =Mod(5;2)=0 = Faux ou 0 La dernière section de la formule : (A1:A5) Saisis ceci dans une formule =A1:A5
Sélectionne le texte A1:A5 et appuie sur F9 tu obtiens la matrice suivante : ={2;4;6;8;10}
Chaque élément de cette matrice représente la valeur contenue dans chacune des cellules de la matrice.
La formule du début : =SOMMEPROD((MOD(LIGNE(A1:A5);2)=0)*(A1:A5)) devient par simple substitution : =SOMMEPROD(({0;1;0;1;0})*{2;4;6;8;10})
En multipliant chaque élément de la première matrice par la valeur correspondante dans l'autre matrice on obtient: 12
La définition de la fonction Sommeprod() selon l'aide d'excel: "Multiplie les valeurs correspondantes des matrices spécifiées et calcule la somme de ces produits" La fonction sommeprod() peut regrouper jusqu'à 30 arguments. On pourrait remplacer le symbole * par le point virgule comme séparateur d'arguments et on aurait ceci : =SOMMEPROD(({0;1;0;1;0});{2;4;6;8;10}) Dernier élément : chacune des matrices doit avoir la même dimension.