Peut-on afficher une autre icone que celle de microsoft dans un classeur ?

Oui c'est possible par macro.

Le code original, écrit pour xl97 est de Jim Rech. 
Il a été modifié de façon à rétablir l'icone originale à la désactivation ou à la fermeture du classeur et de façon à ce que l'icone soit contenue dans le classeur.
(testé avec excel 2010)

Ce code est à mettre dans un module ordinaire :

Option Explicit

Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
(ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
(ByVal hWnd As Long, ByVal wMsg As Long, _
ByVal wParam As Long, lParam As Any) As Long

Declare Function DrawMenuBar Lib "user32" (ByVal hWnd As Long) As Long

Const WM_SETICON = &H80
Const ICON_SMALL = 0
Const ICON_BIG = 1

Sub ChangeXLIcon(Optional ByVal hIcon As Long = 0&)
'code original de Jim Rech
    Dim hWnd As Long
    Dim lngRet As Long
    hWnd = FindWindow("XLMAIN", Application.Caption)
    lngRet = SendMessage(hWnd, WM_SETICON, ICON_SMALL, ByVal hIcon)
    lngRet = SendMessage(hWnd, WM_SETICON, ICON_BIG, ByVal hIcon)
    lngRet = DrawMenuBar(hWnd)
End Sub

La macro ChangeXLIcon est ensuite appellée depuis les wacros événementielles adhoc situées dans le module ThisWorkbook

Private Sub Workbook_Activate()
    ChangeXLIcon (Feuil1.Image1.Picture.Handle)
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    ChangeXLIcon
End Sub

Private Sub Workbook_Deactivate()
    ChangeXLIcon
End Sub

Private Sub Workbook_Open()
    ChangeXLIcon (Feuil1.Image1.Picture.Handle)
End Sub

L'icone (qui doit être un fichier de type ico, bmp, gif, jpeg mais bizarrement pas png) doit être placée dans un contrôle image.
Vous pouvez télécharger un exemple.

Vous pouvez également compléter la personnalisation de votre classeur en changeant le nom qui apparait dans la barre de titre. Par exemple remplacer "mon Classeur.xls Microsoft Excel par Jeu de dames - les jeux intemporels.